Beta Shell v2.0

File Manager

~ /usr/share/perl5/vendor_perl/DateTime/Format

Name	Size	Perms	Modified	Actions
[ .. / .. ]
Builder	-	drwxr-xr-x	2022-02-23 11:28:50	Del
Builder.pm	24.77 KB	-rw-r--r--	2021-04-18 17:23:13	Edit Del
DateParse.pm	2.31 KB	-rw-r--r--	2020-07-30 15:07:10	Edit Del
DateParse.pod	2.41 KB	-rw-r--r--	2020-07-30 15:07:10	Edit Del
Epoch	-	drwxr-xr-x	2022-02-23 11:30:56	Del
Epoch.pm	9.32 KB	-rw-r--r--	2019-11-07 19:47:11	Edit Del
Excel.pm	9.52 KB	-rw-r--r--	2019-08-02 20:14:38	Edit Del
Flexible	-	drwxr-xr-x	2025-05-28 10:09:50	Del
Flexible.pm	40.97 KB	-rw-r--r--	2024-12-31 10:46:26	Edit Del
HTTP.pm	7.44 KB	-rw-r--r--	2014-05-02 14:49:48	Edit Del
ICal.pm	16.8 KB	-rw-r--r--	2020-06-30 16:38:09	Edit Del
ISO8601.pm	31.47 KB	-rw-r--r--	2021-04-12 05:54:19	Edit Del
ISO8601.pod	8.04 KB	-rw-r--r--	2021-04-12 05:54:19	Edit Del
Mail.pm	14.19 KB	-rw-r--r--	2016-06-27 21:30:00	Edit Del
MySQL.pm	6 KB	-rw-r--r--	2019-10-16 11:15:01	Edit Del
Natural	-	drwxr-xr-x	2022-02-23 11:28:50	Del
Natural.pm	24.43 KB	-rw-r--r--	2020-06-26 07:13:35	Edit Del
Pg.pm	27.32 KB	-rw-r--r--	2017-05-04 12:46:26	Edit Del
RFC3339.pm	4.53 KB	-rw-r--r--	2015-10-09 23:21:37	Edit Del
SQLite.pm	5.83 KB	-rw-r--r--	2009-12-10 16:47:28	Edit Del
Strptime	-	drwxr-xr-x	2022-02-23 11:28:49	Del
Strptime.pm	43.66 KB	-rw-r--r--	2017-12-24 17:37:44	Edit Del
W3CDTF.pm	5.71 KB	-rw-r--r--	2017-04-07 20:00:12	Edit Del

Editing: MySQL.pm (6 KB)

package DateTime::Format::MySQL;

use strict;

use vars qw ($VERSION);

$VERSION = '0.06';

use DateTime;
use DateTime::Format::Builder
    ( parsers =>
      { parse_date =>
        { params => [ qw( year month day ) ],
          regex  => qr/^(\d{1,4})[[:punct:]](\d{1,2})[[:punct:]](\d{1,2})$/,
        },

        parse_datetime =>
        [ { params => [ qw( year month day hour minute second ) ],
            regex  => qr/^(\d{1,4})[[:punct:]](\d{1,2})[[:punct:]](\d{1,2})[\sT](\d{1,2})[[:punct:]](\d{1,2})[[:punct:]](\d{1,2})$/,
            extra  => { time_zone => 'floating' },
          },
          { params => [ qw( year month day hour minute second microsecond ) ],
            regex  => qr/^(\d{1,4})[[:punct:]](\d{1,2})[[:punct:]](\d{1,2})[\sT](\d{1,2})[[:punct:]](\d{1,2})[[:punct:]](\d{1,2})\.(\d{1,6})/,
            extra  => { time_zone => 'floating' },
            postprocess => \&_convert_micro_to_nanosecs,
          },
        ],

        parse_timestamp =>
        [ { params => [ qw( year month day hour minute second microsecond ) ],
            regex  => qr/^(\d\d\d\d)(\d\d)(\d\d)(\d\d)(\d\d)(\d\d)\.(\d{1,6})$/,
            extra  => { time_zone => 'floating' },
            postprocess => \&_convert_micro_to_nanosecs,
          },
          { params => [ qw( year month day hour minute second microsecond ) ],
            regex  => qr/^(\d{1,4})[[:punct:]](\d{1,2})[[:punct:]](\d{1,2})[\sT](\d{1,2})[[:punct:]](\d{1,2})[[:punct:]](\d{1,2})\.(\d{1,6})/,
            extra  => { time_zone => 'floating' },
            postprocess => \&_convert_micro_to_nanosecs,
          },
          { length => 14,
            params => [ qw( year month day hour minute second ) ],
            regex  => qr/^(\d\d\d\d)(\d\d)(\d\d)(\d\d)(\d\d)(\d\d)$/,
            extra  => { time_zone => 'floating' },
          },
          {
            params => [ qw( year month day hour minute second ) ],
            regex  => qr/^(\d{1,4})[[:punct:]](\d{1,2})[[:punct:]](\d{1,2})[\sT](\d{1,2})[[:punct:]](\d{1,2})[[:punct:]](\d{1,2})$/,
            extra  => { time_zone => 'floating'},
          },
          { length => 12,
            params => [ qw( year month day hour minute second ) ],
            regex  => qr/^(\d\d)(\d\d)(\d\d)(\d\d)(\d\d)(\d\d)$/,
            extra  => { time_zone => 'floating' },
            postprocess => \&_fix_2_digit_year,
          },
          { length => 10,
            params => [ qw( year month day hour minute ) ],
            regex  => qr/^(\d\d)(\d\d)(\d\d)(\d\d)(\d\d)$/,
            extra  => { time_zone => 'floating' },
            postprocess => \&_fix_2_digit_year,
          },
          { length => 8,
            params => [ qw( year month day ) ],
            regex  => qr/^(\d\d\d\d)(\d\d)(\d\d)$/,
            extra  => { time_zone => 'floating' },
          },
          { length => 6,
            params => [ qw( year month day ) ],
            regex  => qr/^(\d\d)(\d\d)(\d\d)$/,
            extra  => { time_zone => 'floating' },
            postprocess => \&_fix_2_digit_year,
          },
          { length => 4,
            params => [ qw( year month ) ],
            regex  => qr/^(\d\d)(\d\d)$/,
            extra  => { time_zone => 'floating' },
            postprocess => \&_fix_2_digit_year,
          },
          { length => 2,
            params => [ qw( year ) ],
            regex  => qr/^(\d\d)$/,
            extra  => { time_zone => 'floating' },
            postprocess => \&_fix_2_digit_year,
          },
        ],
      },
    );

sub _fix_2_digit_year
{
    my %p = @_;

    $p{parsed}{year} += $p{parsed}{year} <= 69 ? 2000 : 1900;
}

sub format_date
{
    my ( $self, $dt ) = @_;

    return $dt->ymd('-');
}

sub format_time
{
    my ( $self, $dt ) = @_;

    return $dt->hms(':');
}

sub format_datetime
{
    my ( $self, $dt ) = @_;

    return $self->format_date($dt) . ' ' . $self->format_time($dt);
}

# DateTime constructor only has nanosecond. MySQL provides micro
sub _convert_micro_to_nanosecs
{
  my %p = @_;
  my $micro_secs = delete $p{parsed}{microsecond};

  # right pad with zeros
  $micro_secs .= '0' x (6 - length($micro_secs));
  $p{parsed}{nanosecond} = $micro_secs * 1000; 
  return 1; # parse successful
}



1;

__END__

=head1 NAME

DateTime::Format::MySQL - Parse and format MySQL dates and times

=head1 SYNOPSIS

  use DateTime::Format::MySQL;

  my $dt = DateTime::Format::MySQL->parse_datetime( '2003-01-16 23:12:01' );

  # 2003-01-16 23:12:01
  DateTime::Format::MySQL->format_datetime($dt);

=head1 DESCRIPTION

This module understands the formats used by MySQL for its DATE,
DATETIME, TIME, and TIMESTAMP data types.  It can be used to parse
these formats in order to create DateTime objects, and it can take a
DateTime object and produce a string representing it in the MySQL
format.

=head1 METHODS

This class offers the following methods.  All of the parsing methods
set the returned DateTime object's time zone to the floating time
zone, because MySQL does not provide time zone information.

=over 4

=item * parse_datetime($string)

=item * parse_date($string)

=item * parse_timestamp($string)

Given a value of the appropriate type, this method will return a new
C<DateTime> object.  The time zone for this object will always be the
floating time zone, because by MySQL stores the local datetime, not
UTC.

If given an improperly formatted string, this method may die.

=item * format_date($datetime)

=item * format_time($datetime)

=item * format_datetime($datetime)

Given a C<DateTime> object, this methods returns an appropriately
formatted string.

=back

=head1 SUPPORT

Support for this module is provided via the datetime@perl.org email
list.  See http://lists.perl.org/ for more details.

=head1 AUTHOR

Dave Rolsky <autarch@urth.org>

=head1 COPYRIGHT

Copyright (c) 2003-2014 David Rolsky.  All rights reserved.  This program
is free software; you can redistribute it and/or modify it under the
same terms as Perl itself.

The full text of the license can be found in the LICENSE file included
with this module.

=head1 SEE ALSO

datetime@perl.org mailing list

http://datetime.perl.org/

=cut